다운로드 교육자료 문제해결 레퍼런스 구입방법

교육 자료 : 프로세싱 : 키보드 이벤트

오리걸음 경주
오리걸음 경주는 뒤뚱뒤뚱 달려가서 누가 먼저 목표 지점에 도착하는지 시합하는 경주입니다. 뒤뚱뒤뚱 달려가는 동작을 만들어야겠습니다. 왼쪽 바퀴를 중심으로 왼쪽으로 회전하다가 오른쪽 바퀴를 중심으로 오른쪽으로 회전하는 것을 반복하면 뒤뚱뒤뚱 앞으로 달려가게 됩니다.

방향을 바꾸는 명령은 어떻게 전달하면 좋을까요? 방향을 자주 바꾸어야 하기 때문에 컴퓨터 키보드의 스페이스 키를 눌러 명령하도록 해봅시다. 키보드 이벤트는 프로세싱의 keyPressed() 함수와 key 변수를 통해 확인할 수 있습니다.

키보드 이벤트는 프로세싱의 실행 창이 활성화되어 있을 때에만 얻을 수 있습니다. 코드를 실행하면 다음 그림과 같이 실행 창이 나타나면서 활성화되지만 혹시 활성화되어 있지 않은 경우에는 실행 창을 마우스로 클릭하면 활성화됩니다.

import org.roboid.runtime.*;
import org.roboid.hamster.*;
import org.roboid.robot.*;

Hamster hamster;
boolean left = false;

void setup() {
    hamster = Hamster.create(this);
}

void draw() {
}

// 키보드 이벤트가 발생하면 호출된다.
void keyPressed() {
    if(key == ' ') { // 스페이스 키를 눌렀으면
        left = !left; // 방향을 반대로 한다.

        if(left) { // 왼쪽 방향이면
            hamster.wheels(0, 50);
        } else { // 오른쪽 방향이면
            hamster.wheels(50, 0);
        }
    }
}

출발선을 그리고, 목표 지점에도 선을 그립니다. 친구와 함께 오리걸음 경주를 해보도록 합시다.

경주를 좀 더 재미있게 하려면 다음 그림과 같이 종이컵을 세워 놓고 종이컵을 돌아서 다시 출발선으로 돌아오는 경주를 하여도 좋습니다.

햄스터 조종기
키보드의 방향 키를 사용하여 햄스터 조종기를 만들어 봅시다. 위쪽 방향 키는 앞으로 이동, 아래쪽 방향 키는 뒤로 이동, 왼쪽 방향 키는 왼쪽으로 회전, 오른쪽 방향 키는 오른쪽으로 회전하도록 하고, 스페이스 키를 누르면 정지하도록 합시다. 키보드의 방향 키는 특수 키이기 때문에 프로세싱의 keyCode 변수를 확인해야 합니다. 

import org.roboid.runtime.*;
import org.roboid.hamster.*;
import org.roboid.robot.*;

Hamster hamster;

void setup() {
    hamster = Hamster.create(this);
}

void draw() {
}

// 키보드 이벤트가 발생하면 호출된다.
void keyPressed() {
    if(key == ' ') { // 스페이스 키를 눌렀으면
        hamster.stop(); // 정지한다.
    } else if(key == CODED) { // 특수 키인 경우
        if(keyCode == UP) { // 위쪽 방향 키
            hamster.wheels(30); // 앞으로 이동한다.
        } else if(keyCode == DOWN) { // 아래쪽 방향 키
            hamster.wheels(-30); // 뒤로 이동한다.
        } else if(keyCode == LEFT) { // 왼쪽 방향 키
            hamster.wheels(-30, 30); // 왼쪽으로 회전한다.
        } else if(keyCode == RIGHT) { // 오른쪽 방향 키
            hamster.wheels(30, -30); // 오른쪽으로 회전한다.
        }
    }
}

축구 경기장을 만들고 친구와 함께 축구 경기를 해봅시다.
햄스터 피아노
키보드의 알파벳 키를 사용하여 피아노를 만들어 봅시다. 키보드의 a, s, d, f, g, h, j, k, l, ;, ' 키를 순서대로 도, 레, 미, 파, 솔, 라, 시, 도, 레, 미, 파 음으로 하고, 스페이스 키를 누르면 소리를 끄도록 합시다. 작은 따옴표(') 키의 경우에는 작은 따옴표로 감쌀 수 없기 때문에 역 슬래시( \ )를 사용하였음에 주의하세요. 

import org.roboid.runtime.*;
import org.roboid.hamster.*;
import org.roboid.robot.*;

Hamster hamster;

void setup() {
    hamster = Hamster.create(this);
}

void draw() {
}

// 키보드 이벤트가 발생하면 호출된다.
void keyPressed() {
    if(key == ' ') { // 스페이스 키를 눌렀으면
        hamster.note(0); // 소리를 끈다.
    } else if(key == 'a') {
        hamster.note(Hamster.NOTE_C_4); // 도
    } else if(key == 's') {
        hamster.note(Hamster.NOTE_D_4); // 레
    } else if(key == 'd') {
        hamster.note(Hamster.NOTE_E_4); // 미
    } else if(key == 'f') {
        hamster.note(Hamster.NOTE_F_4); // 파
    } else if(key == 'g') {
        hamster.note(Hamster.NOTE_G_4); // 솔
    } else if(key == 'h') {
        hamster.note(Hamster.NOTE_A_4); // 라
    } else if(key == 'j') {
        hamster.note(Hamster.NOTE_B_4); // 시
    } else if(key == 'k') {
        hamster.note(Hamster.NOTE_C_5); // 도
    } else if(key == 'l') {
        hamster.note(Hamster.NOTE_D_5); // 레
    } else if(key == ';') {
        hamster.note(Hamster.NOTE_E_5); // 미
    } else if(key == '\'') {
        hamster.note(Hamster.NOTE_F_5); // 파
    }
}

두 가지를 수정해 봅시다. 첫째, 조건문이 너무 많습니다. switch 문을 사용해 봅시다. 둘째, 같은 키를 두 번 누르면 음이 연결되어 구분이 안 됩니다. 음을 연주하기 전에 잠깐 쉬어주도록 합시다. 

import org.roboid.runtime.*;
import org.roboid.hamster.*;
import org.roboid.robot.*;

Hamster hamster;

void setup() {
    hamster = Hamster.create(this);
}

void draw() {
}

// 키보드 이벤트가 발생하면 호출된다.
void keyPressed() {
    switch(key) {
        case ' ': hamster.note(0); break; // 스페이스 키를 눌렀으면 소리를 끈다.
        case 'a': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_C_4); break; // 도
        case 's': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_D_4); break; // 레
        case 'd': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_E_4); break; // 미
        case 'f': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_F_4); break; // 파
        case 'g': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_G_4); break; // 솔
        case 'h': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_A_4); break; // 라
        case 'j': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_B_4); break; // 시
        case 'k': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_C_5); break; // 도
        case 'l': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_D_5); break; // 레
        case ';': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_E_5); break; // 미
        case '\'': hamster.note(0, 0.05); hamster.note(Hamster.NOTE_F_5); break; // 파
    }
}

공통적인 부분을 함수로 만들면 다음과 같이 좀 더 간략하게 코드를 작성할 수 있습니다. 

import org.roboid.runtime.*;
import org.roboid.hamster.*;
import org.roboid.robot.*;

Hamster hamster;

void setup() {
    hamster = Hamster.create(this);
}

void draw() {
}

void play(int pitch) {
    hamster.note(0, 0.05); // 0.05 박자로 잠시 쉰다.
    hamster.note(pitch);
}

// 키보드 이벤트가 발생하면 호출된다.
void keyPressed() {
    switch(key) {
        case ' ': hamster.note(0); break; // 스페이스 키를 눌렀으면 소리를 끈다.
        case 'a': play(Hamster.NOTE_C_4); break; // 도
        case 's': play(Hamster.NOTE_D_4); break; // 레
        case 'd': play(Hamster.NOTE_E_4); break; // 미
        case 'f': play(Hamster.NOTE_F_4); break; // 파
        case 'g': play(Hamster.NOTE_G_4); break; // 솔
        case 'h': play(Hamster.NOTE_A_4); break; // 라
        case 'j': play(Hamster.NOTE_B_4); break; // 시
        case 'k': play(Hamster.NOTE_C_5); break; // 도
        case 'l': play(Hamster.NOTE_D_5); break; // 레
        case ';': play(Hamster.NOTE_E_5); break; // 미
        case '\'': play(Hamster.NOTE_F_5); break; // 파
    }
}

도#, 미b 등의 반음을 추가하여 완전한 피아노를 만들어 봅시다. 

import org.roboid.runtime.*;
import org.roboid.hamster.*;
import org.roboid.robot.*;

Hamster hamster;

void setup() {
    hamster = Hamster.create(this);
}

void draw() {
}

void play(int pitch) {
    hamster.note(0, 0.05); // 0.05 박자로 잠시 쉰다.
    hamster.note(pitch);
}

// 키보드 이벤트가 발생하면 호출된다.
void keyPressed() {
    switch(key) {
        case ' ': hamster.note(0); break; // 스페이스 키를 눌렀으면 소리를 끈다.
        case 'a': play(Hamster.NOTE_C_4); break; // 도
        case 'w': play(Hamster.NOTE_C_SHARP_4); break; // 도# (레b)
        case 's': play(Hamster.NOTE_D_4); break; // 레
        case 'e': play(Hamster.NOTE_E_FLAT_4); break; // 미b (레#)
        case 'd': play(Hamster.NOTE_E_4); break; // 미
        case 'f': play(Hamster.NOTE_F_4); break; // 파
        case 't': play(Hamster.NOTE_F_SHARP_4); break; // 파# (솔b)
        case 'g': play(Hamster.NOTE_G_4); break; // 솔
        case 'y': play(Hamster.NOTE_G_SHARP_4); break; // 솔# (라b)
        case 'h': play(Hamster.NOTE_A_4); break; // 라
        case 'u': play(Hamster.NOTE_B_FLAT_4); break; // 시b (라#)
        case 'j': play(Hamster.NOTE_B_4); break; // 시
        case 'k': play(Hamster.NOTE_C_5); break; // 도
        case 'o': play(Hamster.NOTE_C_SHARP_5); break; // 도# (레b)
        case 'l': play(Hamster.NOTE_D_5); break; // 레
        case 'p': play(Hamster.NOTE_E_FLAT_5); break; // 미b (레#)
        case ';': play(Hamster.NOTE_E_5); break; // 미
        case '\'': play(Hamster.NOTE_F_5); break; // 파
    }
}
목차
수업 자료 내려 받기
수업 준비
  1. 하드웨어 살펴보기
    		2.  햄스터 · 햄스터S · USB 동글 PDF · PPT
  2. 소프트웨어 설치 (설치 파일을 내려 받은 경우)
    		3.  PDF · PPT
  3. 소프트웨어 설치 (라이브러리 파일을 내려 받은 경우)
    		4.  PDF · PPT
  4. 로봇과 컴퓨터 연결
    		5.  PDF · PPT
  5. 소프트웨어 실행
    		6.  PDF · PPT
  6. 환경 설정
    		7.  PDF · PPT
프로세싱 기초
  1. 도형 그리기
  2. 애니메이션
  3. 마우스와 키보드 이벤트
햄스터 기초
  1. 코드의 기본 형태 만들기
  2. 클라우드 컴퓨터 환경에서 작업하기 (선택 사항)
  3. 말판 이동하기 #1 (순차, 횟수 반복)
  4. 이동하고 회전하기
  5. LED 켜고 소리 내기
  6. 순서대로, 반복하여 명령하기
  7. 키보드 이벤트
  8. 근접 센서 사용하기
  9. 말판 이동하기 #2 (~인 동안 반복)
  10. 바닥 센서 사용하기
  11. 밝기 센서와 가속도 센서 사용하기
  12. 브레이튼버그의 로봇
햄스터 심화
  1. 보드 게임 만들기
  2. 그래픽 인터페이스
  3. 센서 한 개를 사용한 라인 트레이서
  4. 센서 두 개를 사용한 라인 트레이서
  5. 햄스터 친구 따라가기 (2인 1조)
  6. 벽 따라가기
  7. 로봇 청소기 흉내 내기
  8. 라인 트레이서 교차로 주행하기
  9. 미로 탈출
확장 키트
  1. 조립하기
  2. 핀/소켓 배치 살펴보기
  3. 디지털 입력 - 버튼을 누르면 삐 소리가 나요
  4. 디지털 출력 - 어두우면 LED 불이 켜져요
  5. 디지털 출력 - 반짝반짝 LED를 깜박여요
  6. 디지털 출력 - 기울이는 방향으로 LED가 켜져요
  7. 아날로그 입력 - 포텐셔미터를 돌리면 음 높이가 달라져요
  8. 아날로그 입력 - 뜨겁지 않게 해주세요
  9. 아날로그 입력 - 빛을 따라 움직여요
  10. PWM 출력 - LED 불이 부드럽게 밝아졌다 어두워져요
  11. PWM 출력 - LED 촛불이 바람에 흔들려요
  12. 아날로그 서보 출력 - 햄스터 로봇에게 꼬리가 생겼어요
햄스터 고급
  1. 행위 기반의 로봇 제어
  2. 경로 탐색
  3. 자리 바꾸기
Copyright 로봇SW교육원 All rights reserved.
어려운 일이 있으면 광운대학교 로봇학부 박광현 교수(akaii@kw.ac.kr)에게 연락하세요.